::pause>nul,隱藏原暫停文本
echo 這里是自定義文本！ & pause > nul

@echo off
rem 格式：echo 文件內(nèi)容>文件路徑
echo @echo off>test1.bat
::其中>>在文末添加，>覆蓋原內(nèi)容
echo echo this is test>>test1.bat
echo pause>>test1.bat
rem 顯示該文件內(nèi)容
type test1.bat
pause

@echo off
::title設(shè)置標(biāo)題
title 我測試一下！
pause

::if常規(guī)用法，注意空格
@echo off
:start
set /p a=
if not %a%==1 (
	echo 請輸入1
	goto start
) else (
	echo 輸入正確
)
pause>nul

@echo off
if not exist d:\test.bat (
	echo @echo off>d:\test.bat
) else (
	del d:\test.bat
)
pause>nul

@echo off
set a=1
if defined a (
	echo 已定義a
) else (
	echo 未定義a
)
pause>nul

@echo off
set a=123
set b=abc
set c=12
::/i字符串大小寫忽略
if /i %b% equ ABC (
  if %a% geq %c% (
    echo %a%^>=%c%
  ) else (
    echo %a%^<%c%
  )
) else (
  echo %b%不等于ABC
)
pause>nul

::'與'一般用if嵌套實現(xiàn)
@echo off
set /p a=
::當(dāng)a小于10且大于0
if %a% lss 10 if %a% gtr 0 echo 輸入的是0-10
pause

::'非'用not可以實現(xiàn)
@echo off
set /p a=
::a不小于10
if not %a% lss 10 ( echo 輸入的是不小于10 )
pause

::'或'實現(xiàn)一：使用if嵌套（代碼簡潔但邏輯不太好理解）
@echo off
set /p a=請輸入a：
set /p b=請輸入b：
::a小于5或b小于5時
if %a% lss 5 (echo a小于5或b小于5) else (if %b% lss 5 (echo a小于5或b小于5) else (echo a、b都不小于5))
pause

::'或'實現(xiàn)二：使用額外變量標(biāo)記結(jié)果，再判斷該變量（邏輯簡單但代碼多）
@echo off
set /p a=請輸入a：
set /p b=請輸入b：
::a小于5或b小于5時
set flag=0
if %a% lss 5 set flag=1
if %b% lss 5 set flag=1
if %flag% equ 1 ( echo a小于5或b小于5 ) else ( echo a、b都不小于5 )
pause

@echo off
::使用冒號加標(biāo)記名作為goto語句的標(biāo)記
:start
set /p param=
if %param%==4 (echo 請不要輸入4！ & goto start) else (echo %param%)
pause

@echo off
set /p param=請輸入密碼：
echo %param%
pause

::輸出為1
@echo off
set a=1
set a=2&echo %a%
pause

::輸出為2
@echo off&setlocal enabledelayedexpansion
set a=1
set a=2&echo !a!
pause

@echo off
::將0賦值給b
set b=0
echo b:%b%
::將空格和0賦值給a
set a= 0
echo a:%a%
::無法賦值
set c =0
echo c:%c%
pause

@echo off
::查看所有環(huán)境變量
echo ----------------ALL----------------------
set
echo ----------------END----------------------
::查看環(huán)境變量JAVA_HOME的值
if defined JAVA_HOME ( echo JAVA_HOME：%JAVA_HOME% ) else ( echo 未定義JAVA_HOME )
pause

@echo off
set a=1&set b=6
set c=%a%+%b%
::輸出1+6
echo %c%
set d=a+b
::輸出a+b
echo %d%
set /a e=a+b
::輸出7
echo %e%
pause

@echo off
::關(guān)鍵字for、in、do必有，括號必有
::分隔符可以是逗號、分號、等號、空格
::輸出為A換行1換行B。。。
for %%i in (A,B,C) do echo %%i & echo 1
pause>nul

@echo off
::找出D盤下所有文件
for %%i in (d:\*.*) do echo "%%i"
pause

@echo off
set str=c d e f g h i j k l m n o p q r s t u v w x y z
echo 當(dāng)前硬盤的分區(qū)有：
for %%i in (%str%) do if exist %%i: echo %%i:
pause

@echo off
::找出當(dāng)前目錄下文件名為四個字符的txt文件
for %%i in (????.txt) do echo "%%i"
pause

::該文件名為test.bat
@echo off
echo 這是主程序第一個輸出
timeout 2
start test1.bat param1 param2
timeout 2
echo 這是主程序第二個輸出
pause

::該文件名為test1.bat
@echo off
timeout 2
echo 這是子程序第一個輸出
echo 這是接收到的第一個參數(shù)%1 和第二個參數(shù)%2
pause

@echo off
set /p param=
if %param%==4 (echo 請不要輸入4！) else (echo %param%)
::%0在當(dāng)前窗口重新調(diào)用自身
%0

::@echo off
::顯示當(dāng)前目錄
cd
::切換到根目錄
cd\
::盤符加冒號，切換到該盤
d:
::切換到e:hi目錄下(目錄名不區(qū)分大小寫)
cd /d e:\hi
::保存當(dāng)前目錄，并切換當(dāng)前目錄為d:\test
pushd d:\test
::恢復(fù)當(dāng)前目錄為剛才保存的e:\hi
popd
pause

::創(chuàng)建文件夾
md e:\test\test1
::文件夾名有空格需要加引號
md "e:\test op"
::空格隔開，創(chuàng)建多個
md e:\test1 e:\test9\test2 "e:\test5 lmn"

@echo off
::刪除e:\test op下空文件夾,不為空不能刪除
rd "e:\test op"
::刪除e:\test9下所有文件夾,不管是否為空,但會詢問是否確認(rèn)刪除[Y/N]
rd /s e:\test9
::自定義刪除提示信息
echo 是否刪除[Y/N]: & rd /s e:\test9>nul
::/s/q聯(lián)合使用，不會詢問直接刪除
rd /s/q e:\test9

@echo off
::文件夾移動,如果test文件夾存在,則將test5文件夾移動到test文件夾下
::如果test文件夾不存在，則將test5文件夾移動到test1文件夾下并重命名為test
::注意：文件夾移動不能跨分區(qū)
move e:\test5 e:\test1\test
::將d:\test\1.txt文件移動到e:\下并重命名為23.txt
::如果該目錄已存在23.txt,則會覆蓋
move d:\test\1.txt e:\23.txt>nul&&echo 移動成功并重命名
::將e:\23.txt文件移動到e:\test文件夾下
move e:\23.txt e:\test>nul&&echo 移動到文件夾下

@echo off
::刪除該層目錄下的所有文件,需要確認(rèn)[Y/N]
del d:\test
pause
::不需要確認(rèn)
del /q d:\test
::刪除該目錄下所有層級的文件,不刪除文件夾,需要逐個文件夾確認(rèn)
del /s d:\test
::刪除文件111.png,不需要確認(rèn)
del d:\test\111.png

@echo off
::將d:\test\test.txt復(fù)制到e:\test1\目錄下并重命名為test2.txt
::如果test2.txt文件已存在，將自動覆蓋
copy d:\test\test.txt e:\test1\test2.txt
::將e:\test該層目錄下所有文件復(fù)制到d:\test1\test3文件夾下
::前提d:\test1\test3文件夾必須已存在
::相同文件名的文件會被覆蓋
copy e:\test d:\test1\test3

@echo off
::將e:\test目錄下所有文件(夾)復(fù)制到d:\test1
::/e目錄下所有文件(夾),/y已存在時直接覆蓋
xcopy e:\test d:\test1 /e/y

@echo off
cd /d d:\test
::將129.txt和156.txt兩個文件內(nèi)容合并存入新建的new.txt中
copy 129.txt+156.txt new.txt
::打印出new.txt中的內(nèi)容
type new.txt
::將d:\mp3\111.mp3和e:\2.mp3以二進制數(shù)據(jù)合并復(fù)制到d:\new.mp3
::其中/b二進制,/a文本形式
copy /b d:\mp3\111.mp3+e:\2.mp3 d:\new.mp3

@echo off
::將1.txt重命名為58.bat
ren d:\test\1.txt 58.bat
::將d:\test\目錄下所有文件名為1開頭的txt文件改為bat文件
ren d:\test\1*.txt *.bat
::將d:\test\目錄下所有文件名為1開頭三個字符的bat改為txt文件
ren d:\test\1??.bat ???.txt

::該文件名為test.bat
@echo off
echo 這是主程序第一個輸出
timeout 2
call test1.bat param1 param2
timeout 2
echo 這是主程序第二個輸出
pause

::該文件名為test1.bat
@echo off
timeout 1
echo 這是子程序第一個輸出
echo 這是接收到的第一個參數(shù)%1 和第二個參數(shù)%2
pause

@echo off
set a=1
:start
echo %a%&set /a a=a+1
timeout 1 > nul
goto start
pause

@echo off
::每隔一秒輸出斐波拉契數(shù)列
set a=1
set b=1
echo %a%&timeout 1 >nul
echo %b%&timeout 1 >nul
:start
set /a c=a+b
echo %c%&set a=%b%&set b=%c%
timeout 1 > nul
goto start
pause

@echo off
::打開test.txt文件
start e:\test.txt
::啟動jar包
start java -jar e:\demo.jar
pause

::一、MSG命令方式
@echo off
::/time:5設(shè)置時間彈框的顯示時間為5S,5S后自動關(guān)閉
msg * /time:5 這里是彈窗顯示的文本
pause
::設(shè)置彈窗的多行文本
(echo 這是彈窗的第一行文本
echo 這是第二行文本)|msg * /time:5
pause

::一、調(diào)用VBScript的MsgBox實現(xiàn)彈窗
@echo off
::第二個參數(shù)65的解釋在代碼之后的列表中
mshta vbscript:msgbox("彈窗單行顯示內(nèi)容",65,"彈窗的標(biāo)題")(window.close)
::多行顯示文本可在文本中使用vbCrLf或vbNewLine
set msg="多行顯示vbCrLf這是第二行vbNewLine這是第三行"
mshta vbscript:msgbox(Replace(Replace(%msg%,"vbCrLf",vbCrLf),"vbNewLine",vbNewLine),6,"自定義標(biāo)題")(window.close)

@ echo off
%1 %2
ver|find "5.">nul&&goto :Admin
mshta vbscript:createobject("shell.application").shellexecute("%~s0","goto :Admin","","runas",1)(window.close)&goto :eof
:Admin
::上面這段代碼之后執(zhí)行的所有東西都是管理員權(quán)限方式

@echo off
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' NEQ '0' (
	echo 請求管理員權(quán)限...
	goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
echo 獲得管理員權(quán)限
pause

@echo off
::按行讀取d:\test.txt文件中的內(nèi)容,輸出每行的第一個數(shù)據(jù),默認(rèn)每行內(nèi)以空格和tab為分隔符
for /f %%i in (d:\test.txt) do echo %%i
::delims參數(shù)指定分隔符為/
for /f "delims=/" %%i in (d:\test.txt) do echo %%i
::tokens參數(shù)指定讀取第二列,tokens=*讀取所有
for /f "tokens=2 delims=/" %%i in (d:\test.txt) do echo %%i
::skip參數(shù)直接跳過前兩行,從第三行開始
::tokens=2,*讀取第二個和之后剩余所有,%%i為第一列值,%%j為之后剩余所有
::tokens=1,4讀取第一個和第四個,%%i為第一列值,%%j為第四列值
::('net start')表示將單引號內(nèi)語句的執(zhí)行結(jié)果作為集合
for /f "skip=2 tokens=1,* delims=/" %%i in ('net start') do echo %%i %%j
::("asc/2ap/as5")表示對字符串進行處理
for /f "tokens=2,* delims=/" %%i in ("asc/2ap/as5") do echo %%i--%%j
::eol參數(shù)直接忽略以#開頭的行
for /f "eol=# tokens=*" %%i in (d:\test.txt) do echo %%i

@echo off
::關(guān)閉/啟動MySQL服務(wù),執(zhí)行該條語句后會立即執(zhí)行之后的代碼,不會等待停止/啟動的過程
sc stop MySQL
sc start MySQL
::設(shè)置MySQL服務(wù)為自啟動,demand手動,disabled禁用
sc config MySQL start= auto
::安裝服務(wù)
sc create MySQL binPath= "F:\installFiles\mysql-5.7.1.exe"
::卸載服務(wù)(卸載前先關(guān)閉服務(wù))
sc delete MySQL
::關(guān)閉/啟動MySQL服務(wù),等待停止/啟動的過程,完成后執(zhí)行之后的代碼
net start MySQL
net stop MySQL
::查看所有運行的服務(wù)
net start

@echo off
ping 192.168.0.225
::無休止ping某地址
ping www.baidu.com -t

::可以調(diào)用vb腳本和js腳本
mshta vbscript:window.execScript("alert('hello world!');","javascript")(window.close)
mshta javascript:window.execScript("msgBox('hello world!')(window.close)","vbs")
mshta vbscript:msgbox("彈窗單行顯示內(nèi)容",65,"彈窗的標(biāo)題")(window.close)
mshta vbscript:CreateObject("Wscript.Shell").popup("彈窗內(nèi)容",7,"標(biāo)題",64)(window.close)
::連續(xù)彈二個信息框
mshta vbscript:execute("msgbox ""one BOX"":msgbox ""two BOX"":window.close")

@echo off
set a=1
set b=
if defined a if defined b echo 都搞定了，按任意鍵就可以撤了！&pause>nul &exit
echo 我去！還有沒賦值的？
pause

@echo off
::格式化A盤---請謹(jǐn)慎操作，一般莫搞騷操作
format a:
::用以判斷上一條命令是否執(zhí)行成功，默認(rèn)為0，出錯為1
echo %errorlevel%
::這個很好理解 就是判斷errorlevel為0
if %errorlevel% == 0 echo 搞定
::下面相當(dāng)于判斷errorlevel大于等于0 等同于%errorlevel% GEQ 0 
if errorlevel 0 echo 搞定
::下面相當(dāng)于判斷errorlevel大于等于0且小于1 等同于%errorlevel% == 0
if errorlevel 0 if not errorlevel 1 echo 0
pause

@echo off
echo this is test.bat
echo %errorlevel%
call test1.bat
echo %errorlevel%
pause

@echo off
echo this is test1.bat
echo 按任意鍵結(jié)束test1.bat！&pause>nul &exit /b 123